| Server IP : 127.0.0.2 / Your IP : 18.116.36.23 Web Server : Apache/2.4.18 (Ubuntu) System : User : www-data ( ) PHP Version : 7.0.33-0ubuntu0.16.04.16 Disable Function : disk_free_space,disk_total_space,diskfreespace,dl,exec,fpaththru,getmyuid,getmypid,highlight_file,ignore_user_abord,leak,listen,link,opcache_get_configuration,opcache_get_status,passthru,pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,php_uname,phpinfo,posix_ctermid,posix_getcwd,posix_getegid,posix_geteuid,posix_getgid,posix_getgrgid,posix_getgrnam,posix_getgroups,posix_getlogin,posix_getpgid,posix_getpgrp,posix_getpid,posix,_getppid,posix_getpwnam,posix_getpwuid,posix_getrlimit,posix_getsid,posix_getuid,posix_isatty,posix_kill,posix_mkfifo,posix_setegid,posix_seteuid,posix_setgid,posix_setpgid,posix_setsid,posix_setuid,posix_times,posix_ttyname,posix_uname,pclose,popen,proc_open,proc_close,proc_get_status,proc_nice,proc_terminate,shell_exec,source,show_source,system,virtual MySQL : OFF | cURL : ON | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : ON Directory : /usr/share/augeas/lenses/dist/ |
Upload File : |
module Json =
(* A generic lens for Json files *)
(* Based on the following grammar from http://www.json.org/ *)
(* Object ::= '{'Members ? '}' *)
(* Members ::= Pair+ *)
(* Pair ::= String ':' Value *)
(* Array ::= '[' Elements ']' *)
(* Elements ::= Value ( "," Value )* *)
(* Value ::= String | Number | Object | Array | "true" | "false" | "null" *)
(* String ::= "\"" Char* "\"" *)
(* Number ::= /-?[0-9]+(\.[0-9]+)?([eE][+-]?[0-9]+)?/ *)
let spc = /[ \t\n]*/
let ws = del spc ""
let eol = del spc "\n"
let delim (c:string) (d:string) = del (c . spc) d
let dels (s:string) = del s s
let comma = delim "," ","
let colon = delim ":" ":"
let lbrace = delim "{" "{"
let rbrace = delim "}" "}"
let lbrack = delim "[" "["
let rbrack = delim "]" "]"
let str_store =
let q = del "\"" "\"" in
q . store /[^"]*/ . q . ws (* " Emacs, relax *)
let number = [ label "number" . store /-?[0-9]+(\.[0-9]+)?([eE][+-]?[0-9]+)?/ . ws ]
let str = [ label "string" . str_store ]
let const (r:regexp) = [ label "const" . store r . ws ]
let value0 = str | number | const /true|false|null/
let fix_value (value:lens) =
let array = [ label "array" . lbrack . (Build.opt_list value comma)? . rbrack ] in
let pair = [ label "entry" . str_store . colon . value ] in
let obj = [ label "dict" . lbrace . (Build.opt_list pair comma)? . rbrace ] in
(str | number | obj | array | const /true|false|null/)
(* Typecheck finitely deep nesting *)
let value1 = fix_value value0
let value2 = fix_value value1
(* Process arbitrarily deeply nested JSON objects *)
let rec rlns = fix_value rlns
let lns = ws . rlns