| Server IP : 127.0.0.2 / Your IP : 3.149.246.106 Web Server : Apache/2.4.18 (Ubuntu) System : User : www-data ( ) PHP Version : 7.0.33-0ubuntu0.16.04.16 Disable Function : disk_free_space,disk_total_space,diskfreespace,dl,exec,fpaththru,getmyuid,getmypid,highlight_file,ignore_user_abord,leak,listen,link,opcache_get_configuration,opcache_get_status,passthru,pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,php_uname,phpinfo,posix_ctermid,posix_getcwd,posix_getegid,posix_geteuid,posix_getgid,posix_getgrgid,posix_getgrnam,posix_getgroups,posix_getlogin,posix_getpgid,posix_getpgrp,posix_getpid,posix,_getppid,posix_getpwnam,posix_getpwuid,posix_getrlimit,posix_getsid,posix_getuid,posix_isatty,posix_kill,posix_mkfifo,posix_setegid,posix_seteuid,posix_setgid,posix_setpgid,posix_setsid,posix_setuid,posix_times,posix_ttyname,posix_uname,pclose,popen,proc_open,proc_close,proc_get_status,proc_nice,proc_terminate,shell_exec,source,show_source,system,virtual MySQL : OFF | cURL : ON | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : ON Directory : /usr/share/augeas/lenses/dist/ |
Upload File : |
(*
Module: Up2date
Parses /etc/sysconfig/rhn/up2date
Author: Raphael Pinson <raphink@gmail.com>
About: Reference
This lens tries to keep as close as possible to `man 5 up2date` where possible.
About: License
This file is licenced under the LGPLv2+, like the rest of Augeas.
About: Lens Usage
To be documented
About: Configuration files
This lens applies to /etc/sysconfig/rhn/up2date. See <filter>.
About: Examples
The <Test_Up2date> file contains various examples and tests.
*)
module Up2date =
autoload xfm
(************************************************************************
* Group: USEFUL PRIMITIVES
*************************************************************************)
(* Variable: key_re *)
let key_re = /[^=# \t\n]+/
(* Variable: value_re *)
let value_re = /[^ \t\n;][^\n;]*[^ \t\n;]|[^ \t\n;]/
(* View: sep_semi *)
let sep_semi = Sep.semicolon
(************************************************************************
* Group: ENTRIES
*************************************************************************)
(* View: single_entry
key=foo *)
let single_entry = [ label "value" . store value_re ]
(* View: multi_empty
key=; *)
let multi_empty = sep_semi
(* View: multi_value
One value in a list setting *)
let multi_value = [ seq "multi" . store value_re ]
(* View: multi_single
key=foo; (parsed as a list) *)
let multi_single = multi_value . sep_semi
(* View: multi_values
key=foo;bar
key=foo;bar; *)
let multi_values = multi_value . ( sep_semi . multi_value )+ . del /;?/ ";"
(* View: multi_entry
List settings go under a 'values' node *)
let multi_entry = [ label "values" . counter "multi"
. ( multi_single | multi_values | multi_empty ) ]
(* View: entry *)
let entry = [ seq "entry" . store key_re . Sep.equal
. ( multi_entry | single_entry )? . Util.eol ]
(************************************************************************
* Group: LENS
*************************************************************************)
(* View: lns *)
let lns = (Util.empty | Util.comment | entry)*
(* Variable: filter *)
let filter = incl "/etc/sysconfig/rhn/up2date"
let xfm = transform lns filter